Here you have a asp calendar....
<%option explicit%>
<%response.buffer=true%>
<%
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
'''''''' INSTRUCTIONS
''''''''
'''''''' Ne requiert aucun module externe.
'''''''' No external module required.
''''''''
'''''''' Copier le code dans votre document HTML.
'''''''' Paste the code into your HTML document.
''''''''
'''''''' Ajuster la variable nLang.
'''''''' Adjust nLang variable.
''''''''
'''''''' Copier les images b_prev.gif/b_suiv.gif dans le même dossier.
'''''''' Copy b_prev.gif/b_suiv.gif images into the same directory.
''''''''
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Dim nLang ' Langue utilisée
Dim nDate ' Date du calendrier
Dim nURL ' URL de la page
Dim nDatePrev ' Mois précédent
Dim nDateSuiv ' Mois suivant
Dim nJour ' Jour du calendrier
Dim nMois ' Mois du calendrier
Dim nAnnee ' Année du calendrier
Dim nDate1 ' Date du premier jour du mois
Dim nJour2 ' Dernier jour du mois
Dim nDate2 ' Date du dernier jour du mois
Dim nDateDebut ' Première journée de la semaine
Dim nDateFin ' Dernière journée de la semaine
Dim nbrCase ' Nombre de case total du calendrier
Dim nNomJour ' Jour de la semaine pour boucle
Dim n ' Compteur pour boucle
' '''''''''''''''''''''''''''''''''''''''''''
' en = english
' autre = langue des tableaux plus bas
' other = array language, see nMoisNom...
' '''''''''''''''''''''''''''''''''''''''''''
nLang = "en"
' '''''''''''''''''''''''''''''''''''''''''''
' Récupération de la date du la requète http
' Utilisation de la date courrante si aucune.
' '''''''''''''''''''''''''''''''''''''''''''
if request("date") = "" then
nDate = Date()
else
nDate = cDate(request.querystring("date"))
end if
' '''''''''''''''''''''''''''''''''''''''''''
' Configuration des variables
' '''''''''''''''''''''''''''''''''''''''''''
nURL = Request.ServerVariables("URL")
nDatePrev = DateAdd("m", -1, nDate)
nDateSuiv = DateAdd("m", 1, nDate)
nJour = Day(nDate)
nMois = Month(nDate)
nAnnee = Year(nDate)
nDate1 = DateSerial(nAnnee, nMois, 1)
Dim nTemp
nTemp = DateAdd("m", 1, nDate1)
nJour2 = Day(DateAdd("d", -1, nTemp))
nDate2 = DateSerial(nAnnee, nMois, nJour2)
nDateDebut = WeekDay(nDate1, vbSunday)
nDateFin = WeekDay(nDate2, vbSunday)
nbrCase = Day(nDate2) + (nDateDebut-1) + (7-nDateFin)
nNomJour = 1
%>
<html>
<head>
<title>Calendrier</title>
<meta name="keywords" lang="fr-ca" content="Calendrier ASP, CALENDRIER ASP, calendrier dynamique asp, DateSerial, WeekDay, bilingue, calendar, jour, Day, Month, year, DateAdd, Trucsweb, Oznog, webmaster, HTML dynamique, Active Server Page, asp, iis, microsoft, date, mois, année, Cascading style sheet, css, webmestre, internet, www, web, django, Québec, Canada, quebec" />
<meta http-equiv="content-style-Type" content="text/css" />
<style>
TH.calMois { font-size : 10px; font-weight: bold; text-align : center; font-family : verdana, geneva, helvetica, sans-serif; color : #ffffff; background : #7B849C; }
TD.calSing { font-size : 9px; text-align : center; font-family : verdana, geneva, helvetica, sans-serif; color : #000000; background : #7B849C; }
TD.calSemaine { font-size : 9px; font-family : verdana, geneva, helvetica, sans-serif; color : #000000; background : #B5B5C6; }
TD.calJour { font-size : 9px; text-align : center; font-family : verdana, geneva, helvetica, sans-serif; color : #000000; background : #C0C8D6; }
TD.calJour A { font-size : 9px; text-align : center; font-family : verdana, geneva, helvetica, sans-serif; color : #000000; background : #C0C8D6; text-decoration: none; }
TD.calJour A:hover { font-size : 9px; text-align : center; font-family : verdana, geneva, helvetica, sans-serif; color : #ffffff; background : #C0C8D6; text-decoration: none; }
TD.calJourSel { font-size : 9px; font-weight: bold; text-align : center; font-family : verdana, geneva, helvetica, sans-serif; color : #000000; background : #EEEEEE; }
</style>
<!-- *********** -->
<!-- * Fin CSS * -->
<!-- *********** -->
</head>
<body bgcolor="#ffffff">
<center>
<table border="0" cellspacing="1" cellpadding="0" vspace="0" hspace="0">
<!-- Début en-tête mois, année et bouton -->
<tr>
<th class="calMois"><a href="<%=nURL%>?date=<%=nDatePrev%>"><img src="b_prev.gif" width="14" height="13" border="0" vspace="2" align="absmiddle" alt="previous month"></a></th>
<% if nLang = "en" then %>
<th colspan="5" class="calMois"><%=MonthName(nMois)%> <%=nAnnee%></th>
<% end if %>
<th class="calMois"><a href="<%=nURL%>?date=<%=nDateSuiv%>"><img src="b_suiv.gif" width="14" height="13" border="0" vspace="2" align="absmiddle" alt="next month"></a></th>
</tr>
<!-- Fin en-tête mois, année et bouton -->
<!-- Début en-tête des jours -->
<tr>
<% for n = 1 to 7 %>
<% if nLang = "en" then %>
<td width="14%" align="center" valign="middle" class="calSemaine"><%=WeekDayName(n, true, vbSunday)%></td>
<% end if %>
<% next ' Boucle des noms du jour %>
</tr>
<!-- Fin en-tête des jours -->
<!-- Début boucle des jours -->
<%
Dim njTemp
For n = 1 to nbrCase
njTemp = n - nDateDebut+1
if nNomJour = 1 then response.write "<tr>"
if (njTemp) = nJour then
response.write "<td align=""center"" valign=""middle"" class=""calJourSel"">"
else
response.write "<td align=""center"" valign=""middle"" class=""calJour"">"
end if
if n < (nDateDebut) or n > (nJour2+nDateDebut-1) then
response.write " "
else
if (njTemp) = nJour then
response.write (njTemp)
else
response.write "<a href="""&nURL&"?date="&DateSerial(nAnnee, nMois, njTemp)&""">"
response.write (njTemp) & "</a>"
end if
end if
response.write "</td>"
if nNomJour = 7 then response.write "</tr>"
if nNomJour = 7 then nNomJour = 1 else nNomJour = nNomJour + 1 end if
next
' Boucle des jour
%>
<!-- Fin boucle des jours -->
</table>
<form action="recherchelivre.asp" method="post">
<input type="submit" value="Recherche ">
</form>
</body>
</html>