hi,
here is the code i retrieve from www.aspfaq.com (http://www.aspfaq.com) . I used this example then worked from there.
<%
set conn = Server.CreateObject("ADODB.Connection")
conn.open "<connection_string>"
' tell me how many records you want per page
perPage = 50
' set up a query to get the count, and another to get the data
countSQL = "SELECT count(artist) FROM CDs"
dataSQL = "SELECT artist,title,cdn FROM CDs"
' start getting the data, first we need to know the count
' this will tell us how many pages there will be
set rs = conn.execute(countSQL)
counter = clng(rs(0))
rs.close: set rs = nothing
' determine if anything is returned. If there are records,
' figure out the pagecount and the total number of records.
if counter < 1 then
Response.Write "No records found."
Response.End
else
if counter = 1 then perpage = 1
totalRecords = counter
pageCount = clng(counter/perpage)
if counter/perPage > pageCount then
pageCount = pageCount + 1
end if
' what page are we on?
currentpage = clng(request.form("currentpage"))
if currentpage <= 1 then
currentpage = 1
elseif currentpage > pageCount then
currentpage = pagecount
end if
cp = currentPage
response.Write "<form method=post action=rsPage.asp "
response.Write "name=spform><b>Aaron's CDs</b> ... "
response.Write "count = " & counter & "</b> ... Jump to"
response.Write " page #<select name=currentpage "
response.Write "onchange='document.spform.submit();'>"
for i = 1 to pageCount
thisOpt = "<option value='" & i & "'>" & i
' highlight the current page!
response.Write replace(thisOpt," value='" & cp &_
"'", " value='" & cp & "' SELECTED")
next
Response.Write "</select></form><p>"
Response.Write "<p><table border=0 cellpadding=4 "
Response.Write "cellspacing=0 style='border:1px solid #999999'>"
end if
' set up the first record to move to, if applicable
if pageCount > 1 then
startrecord = (clng(currentpage-1) * perpage) + 1
end if
' let's get the data, move to the first record if necessary
' loop through, returning records until we meet perpage or EOF
set rs = conn.execute(dataSQL)
'if counter > perpage and startrecord > 1 then
rs.move(startrecord-1)
for x = 1 to perpage
if rs.eof then exit for
response.write "<tr valign=middle><td>"
artist = rs(0)
if artist <> prevArtist then
prevArtist = artist
if rs(2) then
artist = "<img src=leaf.gif><b>" & artist & "</b>"
else
artist = "<b>" & artist & "</b>"
end if
else
artist = " <span style='color:#999999'>" & artist & "</span>"
end if
response.write "<nobr>" & artist & "</nobr></td><td>"
response.write "<nobr>" & rs(1) & "</nobr></td></tr>"
rs.movenext
next
response.write "</table>"
' clean up
rs.close: set rs = nothing
conn.close: set conn = nothing
%>