I am redesigning my companies website using Wordpress as I like it, etc.

I have an old domain registration script that I still want to use

Ive got the new wordpress page loading and submitting the form to an iframe which accesses the asp script, all working fine

However I need help with the following as I cant figure out how to do it

When a customer searches for a domain name it displays the result underneath, but what I also want it to do if its available is to display a buy now link or button, but this is where the extra hassle comes in as I need to specify pricing details for certain domains, which then outputs to my .asp ordering forms.

Here is my code as it stands now

HTML Code:
<% Option Explicit %>
<% 

'Set the response buffer to true
Response.Buffer = False 

'Set the script timeout to 90 seconds
Server.ScriptTimeout = 90

'Whois function to query the whois server
Private Function whoisResult(whoisURL, strMethod, strCheckString)

	'Dimension variables
	Dim objXMLHTTP			'Holds the XML HTTP Object
	Dim strWhoisResultString	'Holds the reult of the whois query

	'Create an XML object to query the remote whois server
	Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
	
	'Alternative XML HTTP component, for version 3.0 of XMLHTTP
  	'Set objXMLHTTP = Server.CreateObject("MSXML2.ServerXMLHTTP")

	'Open a connection to the remote whois server
        objXMLHTTP.Open strMethod, whoisURL, False
        
        'Send the request and return the data
        objXMLHTTP.Send
        
        'Place the whois registry response into the result string
        strWhoisResultString = objXMLHTTP.ResponseText
        
        'If the domain name is to short then tell them it's invalid
        If Len(strDomainName) < 3 Then
        	
        	'Set the return result of the function to not valid
        	whoisResult = "Not Valid - must be at least 3 characters"
        
        'Check the whois result to see if a result has NOT been found
        ElseIf InStr(1, strWhoisResultString, strCheckString, vbTextCompare) Then
        	
        	'Set the return result of the function to available
        	whoisResult = "Available for registration, Please click buy now below to register your domain name with My Company Name"
        	
        'Else if there is an error
        ElseIF InStr(1, strWhoisResultString, "Error", vbTextCompare) Then
        	
        	'Set the return result of the function to Taken
        	whoisResult = "An Error has occured, please try searching again"
        	
        'Else there was a result
        Else
        	
        	'Set the return result of the function to Taken
        	whoisResult = "Is currently not available for registration, please try an alternative name"
        End If
      
        'Clean up
        Set objXMLHTTP = Nothing
        
End Function


'Function to strip non alphanumeric characters
Private Function characterStrip(strTextInput)

	'Dimension variable
	Dim intLoopCounter 	'Holds the loop counter
	
	'Loop through the ASCII characters up to - hyphen
	For intLoopCounter = 0 to 44
		strTextInput = Replace(strTextInput, CHR(intLoopCounter), "", 1, -1, 0) 
	Next
	
	'Loop through the ASCII characters from hyphen to numeric charcaters
	For intLoopCounter = 46 to 47
		strTextInput = Replace(strTextInput, CHR(intLoopCounter), "", 1, -1, 0) 
	Next
	
	'Loop through the ASCII characters numeric characters to lower-case characters
	For intLoopCounter = 58 to 96
		strTextInput = Replace(strTextInput, CHR(intLoopCounter), "", 1, -1, 0) 
	Next
	
	'Loop through the extended ASCII characters
	For intLoopCounter = 123 to 255
		strTextInput = Replace(strTextInput, CHR(intLoopCounter), "", 1, -1, 0) 
	Next
	
	'Return the string
	characterStrip = strTextInput
	
End Function


'Dimension variables
Dim strDomainName	'Holds the domain name to search for
Dim strSuffix		'Holds the domain name suffix to search

'Read in the domain name to search
strDomainName = Trim(Request.QueryString("domain"))
strSuffix = Trim(Request.QueryString("suffix"))

'If a domain name has been entered then strip any unwanted characters from it
If strDomainName <> "" Then
	
	'Convert the domain name to check to lower case
	strDomainName = LCase(strDomainName)
	
	'Remove www and http from in front
	strDomainName = Replace(strDomainName, "http://", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, "www.", "", 1, -1, 1)
	
	'Remove suffixes
	strDomainName = Replace(strDomainName, ".com", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".net", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".org", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".info", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".biz", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".tv", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".name", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".co.uk", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".org.uk", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".ltd.uk", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".plc.uk", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".net.uk", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".me.uk", "", 1, -1, 1)
	strDomainName = Replace(strDomainName, ".pn.uk", "", 1, -1, 1)

	'Remove any hyphens from the first and last characters
	If Left(strDomainName, 1) = "-" Then strDomainName = Mid(strDomainName, 2, Len(strDomainName))
	If Right(strDomainName, 1) = "-" Then strDomainName = Mid(strDomainName, 1, Len(strDomainName)-1)

	'Remove any hyphens double hyphens
	strDomainName = Replace(strDomainName, "--", "-", 1, -1, 1)
	
	'Strip all non aphanumeric characters from the input
	strDomainName = characterStrip(strDomainName)
End If
%>